par 500 
file 4 alldata
read (4) yr pr perup vol mendo delno state cdfa usfs &
D53 D54 D55 D56 D57 D58 D59 D60 D61 D62 D63 D64 D65 &
D66 D67 D68 D69 D70 D71 D72 D73 D74 D75 D76 D77 D78 D79 D80 D81 D82 D83 &
fstock r10yr lcost fprice r3moch inv inv2 &
oldpro admainr h2s lawndum rwdpro proprcnt parktk1 parktk2 &
hs r3mo gnpd comind clind valres valhome lawnfurn
genr costr = lcost/gnpd
genr prr = pr/gnpd + costr
genr lprr = log(prr) 
genr fpricer = fprice/gnpd + costr
genr lfpricer = log(fpricer)
genr lperup = log(perup)
genr lvol = log(vol) 
genr lvol2 = lvol*lvol
genr lfstock = log(fstock/100000) 
genr lcostr = log(costr)
genr linv = log(inv) 
genr loldpro = log(oldpro)
genr ladmainr = log(admainr) 
genr lhs = log(hs)
genr lperup = log(perup)
genr lr3moch = log(r3moch+3)
genr lr3moch2 = lr3moch*lr3moch
genr cprhs = lprr*lhs
genr iprhs = linv*lhs
genr irhs = lhs * lr3moch
genr lprr2 = lprr*lprr
genr iprr2 = linv*linv
genr linv2 = linv*linv
genr irnv = lr3moch*linv
genr lhs2 = lhs*lhs
genr ipcost = linv*lcostr
genr cpfprice = lprr*lfpricer
genr ipfpr = linv*lfpricer

stat lprr/mean=mp minim=np maxim=op
*set nrc to its 1983 average value
gen1  nrc = 1.77
gen1 i83 = linv:190
gen1 p83 = (lprr:189 +lprr:190)/2
stat lhs / mean=mh minim=nh maxim=oh
stat lr3moch / mean=mr
stat linv/mean=mi minim=ni maxim=oi
stat lvol / mean=mv minim=nv maxim=ov

*demand equation
2sls loldpro lprr lhs lprr2 lhs2 cprhs lperup lvol lvol2 &
mendo delno state cdfa usfs &
(lhs2 iprr2 iprhs lr3moch lhs lr3moch2 &
mendo delno state cdfa usfs &
lperup lvol lvol2 &
lfstock linv ) / rstat 
* test the second order terms for difference from zero
test
test lprr2=0
test lhs2=0
test cprhs=0
end
* housing starts elasticity
* at mean minimum and maximum price
test lhs +cprhs*mp + 2*lhs2*mh=0
test lhs +cprhs*np + 2*lhs2*mh=0
test lhs +cprhs*op + 2*lhs2*mh=0
*
*now test the effects of price mean, minimum and maximum
test lprr + cprhs*mh + 2*lprr2*mp
test lprr + cprhs*mh + 2*lprr2*np
test lprr + cprhs*mh + 2*lprr2*op
*
*the canonical demand curve
*2sls loldpro lprr lhs lperup lvol lvol2 &
*mendo delno state cdfa usfs &
*(r3mo lhs  &
*mendo delno state cdfa usfs &
*lperup lvol lvol2 &
*lfstock linv ) / rstat 
*ols lprr lhs  lperup lvol lvol2 &
*mendo delno state cdfa usfs &
*linv  / rstat
ols lprr lhs lhs2 lperup lvol lvol2 &
  mendo delno state cdfa usfs &
  linv iprr2 iprhs lr3moch lr3moch2 irhs irnv / rstat hetcov
test
test iprr2=0
 test lhs2=0
 test iprhs=0
 test lr3moch2=0
 test irhs=0
 test irnv=0
end
*test housing starts elasticity at means
test lhs +iprhs*mi + 2*lhs2*mh + irhs*mr=0
*
*
*now test the effects of inventory. iprr2==linv2
test linv + iprhs*mh + 2*iprr2*mi + irnv*mr
* n is minimum
test linv + iprhs*mh + 2*iprr2*ni + irnv*mr
*
*
*test r3moch
test lr3moch + 2*lr3moch2*mr + irhs*mh +irnv*mi
*
*
*test the effects of volume n is minimum, o is max
test lvol + lvol2*2*mv
test lvol + lvol2*2*nv
test lvol + lvol2*2*ov
*
*
*
*A System of Two Equations and Some tests
*
*
system 2 &
lhs2 iprr2 iprhs lhs lr3moch lr3moch2 irhs irnv &
mendo delno state cdfa usfs &
lperup lvol lvol2 &
lfstock linv  / rstat dn
ols lprr lhs lhs2 lperup lvol lvol2 &
  mendo delno state cdfa usfs &
  linv iprr2 iprhs lr3moch lr3moch2 irhs irnv
ols loldpro lprr lhs lprr2 lhs2 cprhs lperup lvol lvol2 &
mendo delno state cdfa usfs 
*
* test the hs hypothesis at means	
test lhs:1 +iprhs:1*mi + 2*lhs2:1*mh + irhs:1*mr + (linv:1 &
+ iprhs:1*mh + 2*iprr2:1*mi + irnv:1*mr) *(lhs:2 +cprhs:2*mp &
 + 2*lhs2:2*mh) = 0
*hs with max hs
test lhs:1 +iprhs:1*mi + 2*lhs2:1*oh + irhs:1*mr + (linv:1 &
+ iprhs:1*oh + 2*iprr2:1*mi + irnv:1*mr) *(lhs:2 +cprhs:2*mp &
 + 2*lhs2:2*oh) = 0
*
* test the hs hypothesis at minimum inventory and max price max starts
test lhs:1 +iprhs:1*ni + 2*lhs2:1*oh + irhs:1*mr + (linv:1 &
 + iprhs:1*oh + 2*iprr2:1*ni + irnv:1*mr) *(lhs:2 +cprhs:2*op &
 + 2*lhs2:2*oh) = 0
*
*test the inventory elasticity greater than price elas in demand
test (linv:1 + iprhs:1*mh + 2*iprr2:1*mi + irnv:1*mr ) *&
  (lprr:2 + cprhs:2*mh + 2*lprr2:2*mp) - nrc = 0
*
* n is minimum inventory and o is maximum price
test (linv:1 + iprhs:1*mh + 2*iprr2:1*ni + irnv:1*mr) *&
 (lprr:2 + cprhs:2*mh + 2*lprr2:2*op) -nrc = 0
* tests at the true 1983 values.
test (linv:1 + iprhs:1*mh + 2*iprr2:1*i83 + irnv:1*mr) *&
 (lprr:2 + cprhs:2*mh + 2*lprr2:2*p83) -nrc = 0

*
*
* housing starts elasticity from demand curve
* at mean minimum and maximum price
test lhs:2 +cprhs:2*mp + 2*lhs2:2*mh=0
test lhs:2 +cprhs:2*np + 2*lhs2:2*mh=0
test lhs:2 +cprhs:2*op + 2*lhs2:2*mh=0
* at mean min and max starts
test lhs:2 +cprhs:2*mp + 2*lhs2:2*mh=0
test lhs:2 +cprhs:2*mp + 2*lhs2:2*nh=0
test lhs:2 +cprhs:2*mp + 2*lhs2:2*oh=0
*
*now test the effects of price mean, minimum and maximum from Demand
test lprr:2 + cprhs:2*mh + 2*lprr2:2*mp
test lprr:2 + cprhs:2*mh + 2*lprr2:2*np
test lprr:2 + cprhs:2*mh + 2*lprr2:2*op
*
end
stop